Ergebnis 1 bis 5 von 5

Thema: Excel - 2 Spalten abgleichen und duplikate entfernen oder markieren

  1. #1
    Senior
    Registriert
    Mar 2015
    Beiträge
    186
    Gefällt mir!
    5
    Du gefällst: 53

    Excel - 2 Spalten abgleichen und duplikate entfernen oder markieren

    Hoffe ihr könnt mir bei einem Problem helfen.

    Excel-Tabelle;

    In Tabelle A befinden sich Zeilen mit 807 Werten, In Tabelle B 426 Zeilen mit Werten.

    Tabelle B enthält Werte die auch in Tabelle A zu finden sind. Würde diese gerne miteinander abgleichen und alle Werte die in Tabelle B sind, in Tabelle A löschen oder markieren.

    Habe schon einige Anleitungen/Tips im Internet gefunden, leider sind hier immer beide Tabellen gleich lang. Dies ist aber nicht der Fall.

    Hoffe nun das vielleicht einer von euch mit Excel vertraut ist und mir bei meinem PRoblem helfen kann.

  2. Werbung - Hier werben?
  3. #2
    Ultimatives Spiderschwein Avatar von jbs
    Registriert
    Jun 2015
    Beiträge
    209
    Gefällt mir!
    151
    Du gefällst: 195
    Schau dir das mal an. Musst nur die Tabellennamen und Spalten anpassen und nen Button einauen, der Call CleanDupes ausführt.

    Code:
    Sub CleanDupes()
        Dim targetRange As Range, searchRange As Range
        Dim targetArray
        Dim x As Long
        'Update these 4 lines if your target and search ranges change
        Dim TargetSheetName As String: TargetSheetName = "TabelleA"
        Dim TargetSheetColumn As String: TargetSheetColumn = "A"
        Dim SearchSheetName As String: SearchSheetName = "TabelleB"
        Dim SearchSheetColumn As String: SearchSheetColumn = "A"
    
        'Load target array
        With Sheets(TargetSheetName)
            Set targetRange = .Range(.Range(TargetSheetColumn & "1"), _
                    .Range(TargetSheetColumn & Rows.Count).End(xlUp))
            targetArray = targetRange
        End With
        'Get Search Range
        With Sheets(SearchSheetName)
            Set searchRange = .Range(.Range(SearchSheetColumn & "1"), _
                    .Range(SearchSheetColumn & Rows.Count).End(xlUp))
        End With
        If IsArray(targetArray) Then
            For x = UBound(targetArray) To 1 Step -1
                If Application.WorksheetFunction.CountIf(searchRange, _
                                            targetArray(x, 1)) Then
                    targetRange.Cells(x).EntireRow.Delete
                End If
            Next
        Else
            If Application.WorksheetFunction.CountIf(searchRange, targetArray) Then
                targetRange.EntireRow.Delete
            End If
        End If
    End Sub

  4. #3
    Senior
    THEMENSTARTER


    Registriert
    Mar 2015
    Beiträge
    186
    Gefällt mir!
    5
    Du gefällst: 53
    Danke schonmal für deine Hilfe und schnelle Antwort zu meinem Problem.

  5. #4
    Ultimatives Spiderschwein Avatar von jbs
    Registriert
    Jun 2015
    Beiträge
    209
    Gefällt mir!
    151
    Du gefällst: 195
    Gerne! Probiers mal aus und wenns nicht klappen sollte, einfach melden

  6. #5
    Senior
    THEMENSTARTER


    Registriert
    Mar 2015
    Beiträge
    186
    Gefällt mir!
    5
    Du gefällst: 53
    Hat zwar nicht gleich von anfang an geklappt, aber paar änderungen und es war erfolgreich.

    Danke nochmal. Thread kann geschlossen werden.

Ähnliche Themen

  1. (PHP) - Aus Datenbank IDS im Multi-Dropdown markieren
    Von Uranjitsu im Forum Entwicklung / Programmierung
    Antworten: 1
    Letzter Beitrag: 14.10.2019, 19:43
  2. Wie DRM bei Amazon Video und / oder Netflix entfernen?
    Von ShadowEagle im Forum Szene Daily Talk & OffTopic
    Antworten: 34
    Letzter Beitrag: 31.03.2019, 12:26
  3. (Sonstige) - Excel - Bestimmten Text automatisch in Spalten
    Von Jana-Maria im Forum Entwicklung / Programmierung
    Antworten: 3
    Letzter Beitrag: 01.07.2015, 21:06
  4. szeneBOX.org will verbinden statt spalten
    Von newsBOX im Forum Datenschutz & Privatsphäre (IT-Security)
    Antworten: 3
    Letzter Beitrag: 14.03.2015, 10:27

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •  
SzeneBox.org... im Mittelpunkt der Szene!
© since 2015 szeneBOX.org - All Rights Reserved
Domains: www.szenebox.org