Excel - 2 Spalten abgleichen und duplikate entfernen oder markieren

Hoffe ihr könnt mir bei einem Problem helfen.

Excel-Tabelle;

In Tabelle A befinden sich Zeilen mit 807 Werten, In Tabelle B 426 Zeilen mit Werten.

Tabelle B enthält Werte die auch in Tabelle A zu finden sind. Würde diese gerne miteinander abgleichen und alle Werte die in Tabelle B sind, in Tabelle A löschen oder markieren.

Habe schon einige Anleitungen/Tips im Internet gefunden, leider sind hier immer beide Tabellen gleich lang. Dies ist aber nicht der Fall.

Hoffe nun das vielleicht einer von euch mit Excel vertraut ist und mir bei meinem PRoblem helfen kann.

Schau dir das mal an. Musst nur die Tabellennamen und Spalten anpassen und nen Button einauen, der Call CleanDupes ausführt.

Code:

---

Sub CleanDupes()
    Dim targetRange As Range, searchRange As Range
    Dim targetArray
    Dim x As Long
    'Update these 4 lines if your target and search ranges change
    Dim TargetSheetName As String: TargetSheetName = "TabelleA"
    Dim TargetSheetColumn As String: TargetSheetColumn = "A"
    Dim SearchSheetName As String: SearchSheetName = "TabelleB"
    Dim SearchSheetColumn As String: SearchSheetColumn = "A"

    'Load target array
    With Sheets(TargetSheetName)
        Set targetRange = .Range(.Range(TargetSheetColumn & "1"), _
                .Range(TargetSheetColumn & Rows.Count).End(xlUp))
        targetArray = targetRange
    End With
    'Get Search Range
    With Sheets(SearchSheetName)
        Set searchRange = .Range(.Range(SearchSheetColumn & "1"), _
                .Range(SearchSheetColumn & Rows.Count).End(xlUp))
    End With
    If IsArray(targetArray) Then
        For x = UBound(targetArray) To 1 Step -1
            If Application.WorksheetFunction.CountIf(searchRange, _
                                        targetArray(x, 1)) Then
                targetRange.Cells(x).EntireRow.Delete
            End If
        Next
    Else
        If Application.WorksheetFunction.CountIf(searchRange, targetArray) Then
            targetRange.EntireRow.Delete
        End If
    End If
End Sub

---

Danke schonmal für deine Hilfe und schnelle Antwort zu meinem Problem.

Gerne! Probiers mal aus und wenns nicht klappen sollte, einfach melden :)

Hat zwar nicht gleich von anfang an geklappt, aber paar änderungen und es war erfolgreich.

Danke nochmal. Thread kann geschlossen werden.