Thema: startscript

Für die LID-Sache, die Verschiebung und die Seriennummer sollten wir uns mal kurzzschließen, ich schicke Dir eine PN.

Der Rest dürfte hiermit erschlagen sein. Mein Script sucht sich immer die beiden EXEn aus dem neusten Verzeichnis (Erstellungsdatum des Verzeichnisses und Variable _asustag sind ausschlaggebend, Datum im Verzeichnisnamen wird nicht berücksichtigt).

Deinen Timesync-Code habe ich einfach übernommen, ich gehe davon aus, daß er getestet ist und für Deine Umgebung funktioniert.

Die drei Variablen bei Bedarf einfach anpassen ;-)

Code:

@echo off
:::::::::::::::::::::::::
:: Init - hier koennen die Variablen nach Bedarf angepasst werden

set _root=%~dp0\
set _asustag=WTP
set _activetag=Active

:::::::::::::::::::::::::
PUSHd %_root%
call :GET_NEWEST_DIR
PUSHd %_newestdir%
call :GET_ACTIVE_DIR
POPd
call :TIMESYNC
POPd
start "WindowsActive" "%cd%\%_newestdir%\%_activedir%\WindowsActive.exe"
start "SystemTool" "%cd%\%_newestdir%\asus-wtp\bin\DiagEG.exe"
GOTO:eof

:GET_ACTIVE_DIR:
for /F "tokens=4 usebackq" %%A in (`dir *%_activetag%* ^| find "%_activetag%"`) do set _activedir=%%A
GOTO:eof

:GET_NEWEST_DIR:
for /F "tokens=4,5 usebackq" %%D in (`dir *%_asustag%* /O:D ^| find "%_asustag%"`) do set _newestdir=%%D %%E
GOTO:eof

:TIMESYNC:
W32TM /CONFIG /SYNCFROMFLAGS:MANUAL /MANUALPEERLIST:"PTBTIME1.PTB.DE PTBTIME2.PTB.DE" /RELIABLE:YES 
W32TM /CONFIG /UPDATE 
W32TM /RESYNC /FORCE
NET STOP W32TIME 
NET START W32TIME
GOTO:eof

Cannonau

Edith sagt: Kleinen Kniff eingebaut, falls der Laufwerksbuchstabe des Sticks sich mal ändert ;-)